主题：请问后台程序如何直接调用图表策略？

你可以直接读取a,b策略的虚拟持仓量的变化，把A,B策略当成技术指标。用图表可以这样实现，用轮询，高频扫描。

h1:stkindi('','jycs2.hold1',0,1),linethick0;
h2:stkindi('','jycs3.hold2',0,2),linethick0;
h3:stkindi('','jycs4.hold3',0,18),linethick0;

ha:h1+h2+h3,linethick0;
if holding=0 then
 begin
 buy(ha>0,ha,market);
 buyshort(ha<0,abs(ha),market);
 end
 
if holding<0 and ha<0 and holding<>ha then
 begin
 if holding-ha>0 then
  begin
  buyshort(1,holding-ha,mkt);
  end
 if holding-ha<0 then
  begin
  sellshort(1,abs(holding-ha),mkt);
  end
 end
if holding<0 and ha>0  then
 begin
 sellshort(1,abs(holding),mkt);
 buy(1,ha,mkt);
 end
if holding<0 and ha=0 then
 begin
 sellshort(1,abs(holding),mkt);
 end
 
if holding>0 and ha>0 and holding<>ha then
 begin
 if holding>ha then
  begin
  sell(1,holding-ha,mkt);
  end
 if holding<ha then
  begin
  buy(1,ha-holding,mkt);
  end
 end
if holding>0 and ha<0 then
 begin
 sell(1,holding,mkt);
 buyshort(1,abs(ha),mkt);
 end
if holding>0 and ha=0 then
 begin
 sell(1,holding,mkt);
 end

我不懂后台，主要是图表还没有搞透，改一下应该可以用于后台。用这种方法可以做很多事情的哟！注意尊重他人的劳动成果。

实际发出的信号和A,B发出的信号有延迟，取决于你的环境，我的计算机和网络环境下最大延迟150毫秒