主题：关于MACD的判断公式如何编写

注意：本例采用MACD指标的柱状图分析法，仅按以下思路编写，不适用于直接程序化交易

只做了开仓处理，没有平仓和止损止赢，如果有其它需要，请尝试自己编写

 

至于本帖作者所说的，跨周期调用其它周期低背离，思路和实现方法本例已给出，请尝试自己编写

 

//当绿柱开始收缩时（熊市即将结束，可能反转向上（或低位盘整）），如果出现低背离，则少量建仓

IF all(macd<0,3) and ref(macd,1)<macd and ref(macd,1)<ref(macd,2) THEN

IF  本波截止到目前的绿柱面积〈 前一波绿柱面积                  //柱子面积没有新低

 + 本波绿柱过程中的MACD最低值  〉前一波绿柱中的最低值   //长度没有新低

 + 本波绿柱过程中的最低价   〈  前一波绿柱中的最低价        //价格新低

THEN BUY.

 

//这段信息需要完善

//绿柱消失、红柱开始放出时（下跌行情（或低位盘整）已经结束），如果出现低背离，则加仓

IF ref(macd<0,1) and macd>0 THEN

IF 前一波绿柱面积 〈 更前一波绿柱面积                                      //柱子面积没有新低

 + 最近一波绿柱过程中的MACD最低值  〉更前一波绿柱中的最低值   //长度没有新低

 + 最近一波绿柱过程中的最低价   〈  更前一波绿柱中的最低价        //价格新低

 THEN BUY。

 
此主题相关图片如下：2015112810371853082.jpg

 

variable:gsum=0;  //gsum绿柱总和
variable:glong=0;  //glong最长绿柱
variable:glow=0;   //glow绿柱区域最低价

 

//MACD指标

P:=26;
S:=12;
M:=9;

DIFF := EMA(CLOSE,S) - EMA(CLOSE,P);
DEA  := EMA(DIFF,M);
macd := 2*(DIFF-DEA);

 

gnum:=barslast(ref(macd>0,1) and macd<0);//红转绿
bnum:=barslast(ref(macd<0,1) and macd>0);//绿转红

if ref(macd,1)>0 and macd<0 then
begin
 gsum:=0;    //绿柱开始，清0
 glong:=0;    //绿柱开始，清0
 glow:=low;  //绿柱开始，初始化
end

if macd<0 then
begin
 gsum:=gsum+macd;                                    //累加
 if abs(macd)>abs(glong) then glong:=macd；//如果绿柱更长，则记录
 if low<glow then glow:=low;                         //如果价格更低，则记录
end

 

numb:=max(gnum,bnum)+1;
con1:=abs(gsum)<abs(ref(gsum,numb));//面积小于前一波--面积没创新低
con2:=abs(glong)<abs(ref(glong,numb));//柱子长度小于前一波----长度没创新低
con3:=glow<ref(glow,numb);//价格小于前一波-----价格创新低

 

 

//当绿柱开始收缩时（熊市即将结束，可能反转向上（或低位盘整）），如果出现低背离，则少量建仓

if all(macd<0,3) and ref(macd,1)<macd and ref(macd,1)<ref(macd,2) then
begin
 if con1 and con2 and con3 then buy(1,1,market);//低背离，面积没创新低,长度没创新低,价格创新低
end

 

 

//绿柱消失、红柱开始放出时（下跌行情（或低位盘整）已经结束），如果出现低背离，则加仓
if ref(macd<0,1) and macd>0 then
begin
    if con1 and con2 and con3  then 加:buy(1,1,market);//低背离，面积没创新低,长度没创新低,价格创新低
end