文华改成金字塔交易系统 - 公式模型编写问题提交 - 金字塔客服中心 - 专业程序化交易软件提供商

//参数：

//N: 1 100 14 DMI的N值

//M: 1 30 6 ADX均线周期 ,DMI的M值

//AVGLEN: 10 50 30 最高最低价的EMA周期数

//ENTRYBAR: 1 5 2 保持BUYSETUP触发BAR数

TR:=SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),N);//最高价与最低价做差，最高价与前一周期收盘价做差，最低价与前一周期收盘价作差，在上述三个数据中取绝对值最大者，对该最大值做N周期累加求和。。

HD:=HIGH-REF(HIGH,1);//最高价与前一周期最高价做差

LD:=REF(LOW,1)-LOW;//前一周期最低价与最低价做差

DMP:=SUM(IFELSE(HD>0 && HD>LD,HD,0),N);//如果HD>0并且HD>LD,取HD否则取0,对取值做N周期累加求和。

DMM:=SUM(IFELSE(LD>0 && LD>HD,LD,0),N);//如果LD>0并且LD>HD,取LD否则取0,对取值做N周期累加求和。

PDI:=DMP*100/TR;

MDI:=DMM*100/TR;

ADX:=MA(ABS(MDI-PDI)/(MDI+PDI)*100,M);//MDI与PDI差的绝对值与(MDI+PDI)*100做比值，取该比值的M个周期均值。

ADXR:=(ADX+REF(ADX,M))/2;

UPPERMA:EMA(HIGH,AVGLEN);//计算30根K线最高价的EMA

LOWERMA:EMA(LOW,AVGLEN);//计算30根K线最低价的EMA

CHANSPREAD:=(UPPERMA-LOWERMA)/2;//通过EMA计算出噪音通道宽度

BUYSETUP:=C>UPPERMA&&ADX>REF(ADX,1);//当ADX向上且当前价大于30根K线最高价的EMA满足买入准备条件

BUYTARGET:C+CHANSPREAD;//满足买入准备条件时,用前BAR价格计算出多头触发价

MROBS:=BARSLAST(BUYSETUP);//上次满足买入准备条件距离当前BAR的数目

MROBS<ENTRYBA&&BKVOL=0&&SKVOL=0&&BARPOS>100&&H>=BUYTARGET&&VOL>0,BK;//系统入场

SETSIGPRICETYPE(BK,MAX(OPEN,REF(BUYTARGET,1)));

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=UPPERMA-MINPRICE,SP;//系统出场

SETSIGPRICETYPE(SP,MIN(OPEN,REF(UPPERMA,1)-MINPRICE));

SELLSETUP:=C<LOWERMA&&ADX>REF(ADX,1);//当ADX向上且当前价下于30根K线最低价的EMA满足卖出准备条件

SELLTARGET:C-CHANSPREAD;//满足卖出准备条件时,用前BAR价格计算出空头触发价

MROSS:=BARSLAST(SELLSETUP);//上次满足卖出准备条件距离当前BAR的数目

MROSS<=ENTRYBAR&&BKVOL=0&&SKVOL=0&&BARPOS>100&&LOW<=SELLTARGET&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(SELLTARGET,1)));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=LOWERMA+MINPRICE,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(LOWERMA,1)+MINPRICE));

AUTOFILTER;

上面交易系统是文华的，可以麻烦改为金字塔交易系统吗？

救助，可抽一点时候帮我改吗？

//参数：
//N: 1 100 14   DMI的N值
//M: 1 30 6   ADX均线周期 ,DMI的M值
//AVGLEN: 10 50 30   最高最低价的EMA周期数
//ENTRYBAR: 1 5 2   保持BUYSETUP触发BAR数

input:n(14),m(6),avglen(30),entrybar(2);
TR1:=SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),N);//最高价与最低价做差，最高价与前一周期收盘价做差，最低价与前一周期收盘价作差，在上述三个数据中取绝对值最大者，对该最大值做N周期累加求和。。
HD:=HIGH-REF(HIGH,1);//最高价与前一周期最高价做差
LD:=REF(LOW,1)-LOW;//前一周期最低价与最低价做差
DMP:=SUM(IFELSE(HD>0 and HD>LD,HD,0),N);//如果HD>0并且HD>LD,取HD否则取0,对取值做N周期累加求和。
DMM:=SUM(IFELSE(LD>0 and LD>HD,LD,0),N);//如果LD>0并且LD>HD,取LD否则取0,对取值做N周期累加求和。
PDI:=DMP*100/TR1;
MDI:=DMM*100/TR1;
ADX:=MA(ABS(MDI-PDI)/(MDI+PDI)*100,M);//MDI与PDI差的绝对值与(MDI+PDI)*100做比值，取该比值的M个周期均值。
ADXR:=(ADX+REF(ADX,M))/2;
UPPERMA:EMA(HIGH,AVGLEN);//计算30根K线最高价的EMA
LOWERMA:EMA(LOW,AVGLEN);//计算30根K线最低价的EMA
CHANSPREAD:=(UPPERMA-LOWERMA)/2;//通过EMA计算出噪音通道宽度
BUYSETUP:=C>UPPERMA and ADX>REF(ADX,1);//当ADX向上且当前价大于30根K线最高价的EMA满足买入准备条件
BUYTARGET:C+CHANSPREAD;//满足买入准备条件时,用前BAR价格计算出多头触发价
MROBS:=BARSLAST(BUYSETUP);//上次满足买入准备条件距离当前BAR的数目

m1:=MAX(OPEN,REF(BUYTARGET,1));
if MROBS<ENTRYBAr and holding=0 and BARPOS>100 and H>=BUYTARGET and VOL>0 then buy(holding=0,1,limitr,m1),IGNORECHECKPRICE;//系统入场
//SETSIGPRICETYPE(BK,MAX(OPEN,REF(BUYTARGET,1)));
m2:=MIN(OPEN,REF(UPPERMA,1)-mindiff);
if holding>0 and enterbars>0 and VOL>0 and LOW<=UPPERMA-mindiff then sell(1,0,limitr,m2),IGNORECHECKPRICE;//系统出场
//SETSIGPRICETYPE(SP,MIN(OPEN,REF(UPPERMA,1)-mindiff));

SELLSETUP:=C<LOWERMA and ADX>REF(ADX,1);//当ADX向上且当前价下于30根K线最低价的EMA满足卖出准备条件
SELLTARGET:=C-CHANSPREAD;//满足卖出准备条件时,用前BAR价格计算出空头触发价
MROSS:=BARSLAST(SELLSETUP);//上次满足卖出准备条件距离当前BAR的数目
m3:=MIN(OPEN,REF(SELLTARGET,1));
if MROSS<=ENTRYBAR and holding=0 and BARPOS>100 and LOW<=SELLTARGET and VOL>0 then buyshort(holding=0,1,limitr,m3),IGNORECHECKPRICE;
//SETSIGPRICETYPE(SK,MIN(OPEN,REF(SELLTARGET,1)));
m4:=MAX(OPEN,REF(LOWERMA,1)+mindiff);
if holding<0 and enterbars>0 and VOL>0 and HIGH>=LOWERMA+mindiff then sellshort(1,0,limitr,m4),IGNORECHECKPRICE;
//SETSIGPRICETYPE(BP,MAX(OPEN,REF(LOWERMA,1)+mindiff));

谢谢,能及时解决问题！

另外，怎样在编制公式时输入中文？

要输入在哪里?做什么用的？

新建交易系统，编辑公式时

切换到中文输入法就能输入中文

编辑公式输入中文出现小黑方块，不能显示中文。

上面交易系统模拟交易有信号了，太感谢了！！！

1，交易中出现-2，-1，-3，-4滑点，是指亏滑点钱吗？怎样控制滑点？

2，下面交易系统改成后台交易系统滑点会减少吗？麻烦修改为后台交易系统。

//参数：
//N: 1 100 14   DMI的N值
//M: 1 30 6   ADX均线周期 ,DMI的M值
//AVGLEN: 10 50 30   最高最低价的EMA周期数
//ENTRYBAR: 1 5 2   保持BUYSETUP触发BAR数

1.你的中文到底是要来干什么的？

2.空头持仓

3.滑点和图表或者后台无关

编写公式用，例如：开仓价，平仓价，开多条件，平仓条件

主题：文华改成金字塔交易系统