主题：我的一个日内交易策略，求助编程程序

很简单的程序。但是撤单追单那一部分，要用后台实现

今晚比较闲，给楼主一个答案：

别看代码多，为了使结构清晰化，多用了begin……end，其实逻辑很简单

variable:hl=0,cc=0,kcj=0,zs=0;
cond:=date<>ref(date,1);
nn:=barslast(cond)+1;
hi:=ref(hhv(h,nn),1);
lo:=ref(llv(l,nn),1);
entertime:=time>93000 and time<145800 and hi-lo<=250;

if time>=145800 then begin
 sell(holding>0,1,limitr,o);
 sellshort(holding<0,1,limitr,o);
 cc:=0;
end

if holding>0 then begin
 多盈:kcj+80;
 多损:zs;
end

if holding<0 then begin
 空盈:kcj-80;
 空损:zs;
end

if holding>0 and l<zs then begin
 sell(1,1,limitr,min(o,zs-mindiff));
 cc:=0;
end

if holding<0 and h>zs then begin
 sellshort(1,1,limitr,max(o,zs+mindiff));
 cc:=0;
end

if holding>0 and h>kcj+80 then begin
 sell(1,1,limitr,kcj+80);
 cc:=0;
end

if holding<0 and l<kcj-80 then begin
 sellshort(1,1,limitr,kcj-80);
 cc:=0;
end

if holding=0 and time<145800 and cc>0 and l<hl-50 then begin
 buy(1,1,limitr,hl-50);
 kcj:=hl-50;
 zs:=kcj-75;
 hl:=kcj;
 if l<zs then begin

  sell(1,1,limitr,zs-mindiff);

  cc:=0;

 end
 goto quit@;
end

if holding=0 and time<145800 and cc<0 and h>hl+50 then begin
 buyshort(1,1,limitr,hl+50);
 kcj:=hl+50;
 zs:=kcj+75;
 hl:=kcj;
 if h>zs then begin

  sellshort(1,1,limitr,zs+mindiff);

  cc:=0;

 end
 goto quit@;
end

if holding>0 and h>hl then begin
 hl:=h;
 if hl-kcj>50 then zs:=kcj;
end

if holding<0 and l<hl then begin
 hl:=l;
 if kcj-hl>50 then zs:=kcj;
end

if cc=0 and entertime and h>hi then begin
 cc:=1;
 hl:=h;
end

if cc=0 and entertime and l<lo then begin
 cc:=-1;
 hl:=l;
end

if cc>0 and h>hl then hl:=h;
if cc<0 and l<hl then hl:=l;
quit@;

谢谢斑竹