大神帮我看下

西安斯尔德

帮我看下哪里不对，今天的开盘价大于昨天的收盘价开多，反之开空，在帮我写一句收盘最后一分钟平仓。

INPUT : LOTS(1,1,1000,1);

SSS1:CALLSTOCK(STKLABEL,VTCLOSE,6,-1);
SSS2:CALLSTOCK(STKLABEL,VTOPEN,6,0);

IF  THEN BEGIN
   
    SELLSHORT(SSS1<SSS2,HOLDING,LIMITR, OPEN);
    BUY(SSS1<SSS2,LOTS,LIMITR, OPEN);
   
END

IF  THEN BEGIN
    SELL(SSS1>SSS2,HOLDING,LIMITR, OPEN);
    BUYSHORT(SSS1>SSS2,LOTS,LIMITR, OPEN);
END


当前持仓:HOLDING,COLORRED,LINETHICK0;
当前资产:ASSET,NOAXIS,COLORGRAY;
盈亏比: PAYOFFRATE,COLORMAGENTA;
胜率:PERCENTWIN,COLORYELLOW;

技术009

[PEL] 复制代码

input : lots(1,1,1000,1);

sss1:callstock(stklabel,vtclose,6,-1);
sss2:callstock(stklabel,vtopen,6,0);

if sss1<sss2, then begin
   
    sellshort(1,holding,limitr, open);
    buy(holding=0,lots,limitr, open);
   
end

if sss1>sss2 then begin
    sell(1,holding,limitr, open);
    buyshort(holding=0,lots,limitr, open);
end


if time>=185900 THEN
begin
sell(1,holding,market);
sellshort(1,holding,market);	 
end 

当前持仓:holding,colorred,linethick0;
当前资产:asset,noaxis,colorgray;
盈亏比: payoffrate,colormagenta;
胜率:percentwin,coloryellow;

西安斯尔德

技术009 发表于 2024-2-22 15:40
[mw_shl_code=pel,true]input : lots(1,1,1000,1);

sss1:callstock(stklabel,vtclose,6,-1);

input : lots(1,1,1000,1);
INPUT : HLD(10,1,1000,1);//获利
INPUT : ZSD(30,1,1000,1);//止损
INPUT : QDYD(30,1,1000,1);//移动保护启动点
INPUT : YD(5,1,1000,1);//移动保护
sss1:callstock(stklabel,vtclose,6,-1);
sss2:callstock(stklabel,vtopen,6,0);
TT:=IF(HOLDING<>0,OPENBAR,3);
HHH:=REF(HHV(H,TT+1),1);
LLL:=REF(LLV(L,TT+1),1);
if sss1<sss2, then begin
   
    sellshort(1,holding,limitr, open);
    buy(holding=0,lots,limitr, open);
   
end

if sss1>sss2 then begin
    sell(1,holding,limitr, open);
    buyshort(holding=0,lots,limitr, open);
end
IF HOLDING >0 THEN BEGIN//多单止盈
        BCCJ:=MAX(AVGENTERPRICE+HLD*MINDIFF,OPEN);
        SELL(H>=AVGENTERPRICE+HLD*MINDIFF,HOLDING,LIMITR, BCCJ);
        END
IF HOLDING >0 THEN BEGIN//多单止损
        BCCJ1:=MIN(AVGENTERPRICE-ZSD*MINDIFF,OPEN);
        SELL(L<=AVGENTERPRICE-ZSD*MINDIFF,HOLDING,LIMITR, BCCJ1);
        END
IF HOLDING >0 AND HHH>=AVGENTERPRICE+MINDIFF*QDYD AND ENTERBARS>0 THEN BEGIN//多单止损
        BCCJ2:=MIN(AVGENTERPRICE+YD*MINDIFF,OPEN);
        SELL(L<=AVGENTERPRICE+YD*MINDIFF,HOLDING,LIMITR, BCCJ2);
        END

/////////////////       
IF HOLDING <0 THEN BEGIN//空单止盈
        SCCJ:=MIN(AVGENTERPRICE-HLD*MINDIFF,OPEN);
        SELLSHORT(L<=AVGENTERPRICE-HLD*MINDIFF,HOLDING,LIMITR,SCCJ);
        END       
IF HOLDING <0 THEN BEGIN//空单止损
        SCCJ1:=MAX(AVGENTERPRICE+ZSD*MINDIFF,OPEN);
        SELLSHORT(H>=AVGENTERPRICE+ZSD*MINDIFF,HOLDING,LIMITR,SCCJ1);
        END       
IF HOLDING <0 AND LLL<=AVGENTERPRICE-MINDIFF*QDYD AND ENTERBARS>0 THEN BEGIN//空单止损
        SCCJ2:=MAX(AVGENTERPRICE-YD*MINDIFF,OPEN);
        SELLSHORT(H>=AVGENTERPRICE-YD*MINDIFF,HOLDING,LIMITR,SCCJ2);
        END               


if time>=185900 THEN
begin
sell(1,holding,market);
sellshort(1,holding,market);     
end

当前持仓:holding,colorred,linethick0;
当前资产:asset,noaxis,colorgray;
盈亏比: payoffrate,colormagenta;
胜率:percentwin,coloryellow;

补充内容 (2024-2-22 16:16):
怎么限制交易次数，每天只开一次仓

技术009

只能用全局变量控制：https://www.weistock.com/bbs/for ... &extra=page%3D2

参考这个范例里的做法。

西安斯尔德

技术009 发表于 2024-2-22 16:23
只能用全局变量控制：https://www.weistock.com/bbs/forum.php?mod=viewthread&tid=55&extra=page%3D2

...

能辛苦下给修改吗，新手看的好乱

技术009

[PEL] 复制代码

input : lots(1,1,1000,1);
input : hld(10,1,1000,1);//获利
input : zsd(30,1,1000,1);//止损
input : qdyd(30,1,1000,1);//移动保护启动点
input : yd(5,1,1000,1);//移动保护
variable:num=0;                            // 全局变量,来控制当天交易次数
cs:=1; 
sss1:callstock(stklabel,vtclose,6,-1);
sss2:callstock(stklabel,vtopen,6,0);
tt:=if(holding<>0,openbar,3);
hhh:=ref(hhv(h,tt+1),1);
lll:=ref(llv(l,tt+1),1);
if sss1<sss2 then begin
   
    sellshort(1,holding,limitr, open);
    if num<cs then 
    begin 
    buy(holding=0,lots,limitr, open);
    num:=num+1;
    end 
end

if sss1>sss2 then begin
    sell(1,holding,limitr, open);
    if num<cs then
    begin 
    buyshort(holding=0,lots,limitr, open);
    num:=num+1;
    end 
end
if holding >0 then begin//多单止盈
        bccj:=max(avgenterprice+hld*mindiff,open);
        sell(h>=avgenterprice+hld*mindiff,holding,limitr, bccj);
        end
if holding >0 then begin//多单止损
        bccj1:=min(avgenterprice-zsd*mindiff,open);
        sell(l<=avgenterprice-zsd*mindiff,holding,limitr, bccj1);
        end
if holding >0 and hhh>=avgenterprice+mindiff*qdyd and enterbars>0 then begin//多单止损
        bccj2:=min(avgenterprice+yd*mindiff,open);
        sell(l<=avgenterprice+yd*mindiff,holding,limitr, bccj2);
        end

/////////////////       
if holding <0 then begin//空单止盈
        sccj:=min(avgenterprice-hld*mindiff,open);
        sellshort(l<=avgenterprice-hld*mindiff,holding,limitr,sccj);
        end       
if holding <0 then begin//空单止损
        sccj1:=max(avgenterprice+zsd*mindiff,open);
        sellshort(h>=avgenterprice+zsd*mindiff,holding,limitr,sccj1);
        end       
if holding <0 and lll<=avgenterprice-mindiff*qdyd and enterbars>0 then begin//空单止损
        sccj2:=max(avgenterprice-yd*mindiff,open);
        sellshort(h>=avgenterprice-yd*mindiff,holding,limitr,sccj2);
        end               


if time>=185900 then
begin
sell(1,holding,market);
sellshort(1,holding,market);     
end
if time=closetime(0) then num:=0;  

当前持仓:holding,colorred,linethick0;
当前资产:asset,noaxis,colorgray;
盈亏比: payoffrate,colormagenta;
胜率:percentwin,coloryellow;