转码成金字塔

无畏

        
跨周期数据
A:=SUM((CLOSE-REF(CLOSE,3))/REF(CLOSE,3)*VOL,0),COLORYELLOW;

B:=SMA(A,10,1);//A的N周期的以1为权重的移动平均；
E:=SMA(A,30,1);//A的M周期的以1为权重的移动平均；



BB1:B>E;

AA1:B<E;
DRAWCOLORKLINE(BB1,COLORRED,1);
DRAWCOLORKLINE(AA1,COLORCYAN,1);
空:B<E;
多:B>E;
//主模型
     #IMPORT [MIN,35,XXX] AS VAR
空1:VAR.空;  //跨周期引用
多1:VAR.多;



上轨:EMA(H,Z1),COLORCYAN,LINETHICK1;
下轨:EMA(L,Z1),COLORMAGENTA,LINETHICK1;
A:=SUM((CLOSE-REF(CLOSE,3))/REF(CLOSE,3)*VOL,0),COLORYELLOW;
B:=SMA(A,10,1);//A的N周期的以1为权重的移动平均；
E:=SMA(A,30,1);//A的M周期的以1为权重的移动平均；
BB1:B>E;
AA1:B<E;
DRAWCOLORKLINE(BB1,COLORRED,1);
DRAWCOLORKLINE(AA1,COLORCYAN,1);
AA:=CROSSDOWN(L,下轨+0*MINPRICE);
BB:=CROSS(H,上轨-0*MINPRICE);




多1&&B>E&&AA&&COUNTSIG(BK,BARSLASTCOUNT(BB1))=0&&BB1,BK(1);

空1&&B<E&&BB&&COUNTSIG(SK,BARSLASTCOUNT(AA1))=0&&AA1,SK(1);
C<BKPRICE-20*MINPRICE,SP(BKVOL);

C>SKPRICE+20*MINPRICE,BP(SKVOL);

BARSLASTCOUNT(B<E)=15,SP(1);
BARSLASTCOUNT(B>E)=15,BP(1);
CHECKSIG(BK,'A',0,'C',0,0);
CHECKSIG(SK,'A',0,'C',0,0);
CHECKSIG(BP,'A',0,'C',0,0);
CHECKSIG(SP,'A',0,'C',0,0);
TRADE_OTHER('AUTO');//自动换月
谢谢各位大神，请教

技术009

下单语句，CHECKSIG函数等的替换，在这里已经有所整理了。
https://www.weistock.com/bbs/for ... d=31&extra=page%3D1

至于跨周期调用建议参考我们的函数说明：https://www.weistock.com/docs/PE ... 91%A8%E6%9C%9F.html

如果有一定编写基础，只是对金字塔不编写不熟悉的话，上面这个应该不难处理。

无畏

老师，我没编程基础，想转到金字塔这边做期货，麻烦老师辛苦下帮我改一下

技术009

被调用指标，你自己在金字塔里面新建，名称不能叫var了，这个是我们系统函数名称，这里就叫A吧。，把代码原封不动放进去即可。被调用指标不需要调整和修改。
这2句去掉：
DRAWCOLORKLINE(BB1,COLORRED,1);
DRAWCOLORKLINE(AA1,COLORCYAN,1);

没有直接和DRAWCOLORKLINE效果相等的代码。

然后交易指标：

//自行调整下周期吧。这里暂时调用的是1分钟周期
空1:STKINDI('','A.空',0,1,0);  
多1:STKINDI('','A.多',0,1,0); ;



上轨:EMA(H,Z1),COLORCYAN,LINETHICK1;
下轨:EMA(L,Z1),COLORMAGENTA,LINETHICK1;
A:=SUM((CLOSE-REF(CLOSE,3))/REF(CLOSE,3)*VOL,0),COLORYELLOW;
B:=SMA(A,10,1);//A的N周期的以1为权重的移动平均；
E:=SMA(A,30,1);//A的M周期的以1为权重的移动平均；
BB1:B>E;
AA1:B<E;

AA:=CROSS(下轨+0*MINPRICE,L);
BB:=CROSS(H,上轨-0*MINPRICE);

VARIABLE:bx:=0,ax:=0;
if bb1 then bx:=bx+1;
if not(bb1) then bx:=0;
if aa1 then ax:=ax+1;
if not(aa1) then ax:=0;




if 多1 and  B>E and AA and ENTERBARS>=bx and BB1 then buy(holding=0,1,market);

if 空1 and B<E and BB and  ENTERBARS>=ax and  AA1 then buyshort(holding=0,1,market);
if C<AVGENTERPRICE-20*MINDIFF then sell(1,0,market);

if C>AVGENTERPRICE+20*MINDIFF  then sellshort(1,0,market);


VARIABLE:bx2:=0,ax2:=0;
if B<E then bx2:=bx2+1;
if not(B<E) then bx2:=0;
if B>E then ax2:=ax2+1;
if not(B>E) then ax2:=0;



if bx2=15 then sell(1,0,market);
if ax2=15 then sellshort(1,0,market);
还有些参数没定义，你自行补齐下。如果没有编写基础的话，建议学习下。论坛上通常是不会负责编写完整策略的。