求教：开平仓指标编写

张先生413

最近流行的六脉神剑指标“六红买，三绿卖”，
问题1：根据副图的六脉神剑指标，竖列出现“六个红箭头开多，三个绿箭头平仓”；”六个绿箭头开空，三个红箭头平仓”，怎么编写交易系统？
问题2：开平仓以后，怎么在K线图上画出来？



指标代码如下：

DIFF:=EMA(CLOSE,8)-EMA(CLOSE,13);
DEA:=EMA(DIFF,5);
A1:=DIFF>DEA;//MACD金叉
B1:=DIFF<DEA;//MACD死叉
DRAWICON(DIFF>DEA,1,4);
DRAWICON(DIFF<DEA,1,5);
DRAWTEXT(ISLASTBAR=1,1,' MACD'),COLORBROWN;


RSV1:=(CLOSE-LLV(LOW,8))/(HHV(HIGH,8)-LLV(LOW,8))*100;
K:=SMA(RSV1,3,1);
D:=SMA(K,3,1);
A2:=K>D;//KD金叉
B2:=K<D;//KD死叉
DRAWICON(K>D,2,4);
DRAWICON(K<D,2,5);
DRAWTEXT(ISLASTBAR=1,2,' RSV'),COLORBROWN;


LC:=REF(CLOSE,1);
RSI1:=(SMA(MAX(CLOSE-LC,0),5,1))/(SMA(ABS(CLOSE-LC),5,1))*100;
RSI2:=(SMA(MAX(CLOSE-LC,0),13,1))/(SMA(ABS(CLOSE-LC),13,1))*100;
A3:=RSI1>RSI2;
B3:=RSI1<RSI2;
DRAWICON(RSI1>RSI2,3,4);
DRAWICON(RSI1<RSI2,3,5);
DRAWTEXT(ISLASTBAR=1,3,' RSI'),COLORBROWN;


RSV:=-(HHV(HIGH,13)-CLOSE)/(HHV(HIGH,13)-LLV(LOW,13))*100;
LWR1:=SMA(RSV,3,1);
LWR2:=SMA(LWR1,3,1);
A4:=LWR1>LWR2;
B4:=LWR1<LWR2;
DRAWICON(LWR1>LWR2,4,4);
DRAWICON(LWR1<LWR2,4,5);
DRAWTEXT(ISLASTBAR=1,4,' LWR'),COLORBROWN;


BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
A5:=CLOSE>BBI;
B5:=CLOSE<BBI;
DRAWICON(CLOSE>BBI,5,4);
DRAWICON(CLOSE<BBI,5,5);
DRAWTEXT(ISLASTBAR=1,5,' BBI'),COLORBROWN;


MTM:=CLOSE-REF(CLOSE,1);
MMS:=100*EMA(EMA(MTM,5),3)/EMA(EMA(ABS(MTM),5),3);
MMM:=100*EMA(EMA(MTM,13),8)/EMA(EMA(ABS(MTM),13),8);
A6:=MMS>MMM;
B6:=MMS<MMM;
DRAWICON(MMS>MMM,6,4);
DRAWICON(MMS<MMM,6,5);
DRAWTEXT(ISLASTBAR=1,6,' MTM'),COLORBROWN;


买入:IF((A1 AND A2 AND A3 AND A4 AND A5 AND A6) AND REF(A1 AND A2 AND A3 AND A4 AND A5 AND A6,1)=0,7,0),COLORBLACK,LINETHICK3;
上涨:IF(A1 AND A2 AND A3 AND A4 AND A5 AND A6,7,0),COLORBLUE,LINETHICK2;

卖出:IF((B1 AND B2 AND B3 AND B4 AND B5 AND B6) AND REF(B1 AND B2 AND B3 AND B4 AND B5 AND B6,1)=0,7,0),COLORGRAY,LINETHICK4;
下跌:IF(B1 AND B2 AND B3 AND B4 AND B5 AND B6,7,0),COLORMAGENTA,LINETHICK3;

技术009

这部分代码加入进去：

rct:=(DIFF>DEA) +(K>D) + (RSI1>RSI2) + (LWR1>LWR2)+(CLOSE>BBI)+(MMS>MMM);

kd:rct=6;
pd:rct<=3;//绿箭头大于等于三个平多
kk:rct=0;
pk:rct>=3;//红箭头大于等于三个平空

buy(kd and holding=0,1,market);
sell(pd,holding,market);

buyshort(kk and holding=0,1,market);
sellshort(pk,holding,market);

张先生413

请教：
1.开盘2分钟后开单，收盘前2分钟不开单；收盘前平所有单，策略怎么编写？
2.过滤震荡行情，有什么好的策略？

技术009

1.
kd:rct=6;
pd:rct<=3;//绿箭头大于等于三个平多
kk:rct=0;
pk:rct>=3;//红箭头大于等于三个平空

//时间控制在1分钟周期比较精确
tcon:time>010200 and time<185800;
buy(kd and holding=0 and tcon,market);
sell(pd,holding,market);

buyshort(kk and holding=0 and tcon,1,market);
sellshort(pk,holding,market);

if time>=185800 then
begin
收盘平空:sellshort(1,holding,market);
收盘平多:sell(1,holding,market);
end


2.我们是无法提供策略思路的。

张先生413

求教：1.如果一个订单亏损100元，自动止损；

张先生413

2.如果一个订单亏损10个最小交易单元，自动止损；

张先生413

3.如果一个订单盈利50个最小交易单元，自动止盈；

张先生413

4.一个订单盈利，如果回撤此订单盈利金额的30%，自动止盈。怎么编码，感谢。

技术006

1,2本质上都一样，无非是表达方式不同而已。以多头为例：

//止盈50个变动价位
IF C-AVGENTERPRICE>50*MINDIFF THEN BEGIN
SELL(1,HOLDING,MARKET);
END

//止损10个变动价格。或者AVGENTERPRICE-C>100
IF AVGENTERPRICE-C>10*MINDIFF THEN BEGIN
SELL(1,HOLDING,MARKET);
END


DTYDZS:=(HHV(H,ENTERBARS)-CLOSE)/AVGENTERPRICE>=0.3;
SELL(DTYDZS,0,MARKET);