请老师修改

100020711

M1:EMA(CLOSE,50);

KCH:= REF(HIGH,ENTERBARS);
KCL:= REF(LOW,ENTERBARS);
KCQH:= ref(hhv(high,10),enterbars);
KCQL:= ref(LLv(LOW,10),enterbars);
DZY:= ENTERPRICE+(ENTERPRICE-REF(LLV(LOW,10),ENTERBARS))*2;
KZY:= ENTERPRICE-(REF(HHV(HIGH,10),ENTERBARS)-ENTERPRICE)*2;

KD:= CROSS(C,M1) ; //开多条件
PD1:= C<KCL or c<m1 ;               //开仓k最低价平多
PD2:= C<KCQL ;                      //开仓k前低点平多
PD3:= C>= DZY;                      //收盘大于等于2：1盈亏比平多

KK:= CROSS(M1,C) ; //开空条件
PK1:= C>KCH or c>m1 ; //平空条件
PK2:= C>KCQH ; //平空条件
PK3:= C<= KZY; //平空条件

平空1:SELLSHORT(PK1,1,THISCLOSE);//平空信号
平空2:SELLSHORT(PK2,1,THISCLOSE);//平空信号
平空3:SELLSHORT(PK3,1,THISCLOSE);//平空信号

开多:BUY(KD AND HOLDING=0,1,THISCLOSE); //开多信号
平多1:SELL(PD1,1,THISCLOSE);//平多信号
平多2:SELL(PD2,1,THISCLOSE);//平多信号
平多3:SELL(PD3,1,THISCLOSE);//平多信号

开空:BUYSHORT(KK AND HOLDING=0,1,THISCLOSE);//开空信号
请老师帮忙给上面的代码加上全局变量的案例，我好参考学习，感谢！

技术006

这是1楼的代码，针对性的调整代码顺序。触发条件的因子计算遵循就近原则。对你的代码情况也可以理解成随用随取。如果你想对比自己原来代码存在的问题，可以输出每个条件的值，以及ENTERBARS和ENTERPRICE在相应存在问题的k上逐句分析结果产生的原因，这样更有利于理解代码逻辑问题。

M1:EMA(CLOSE,50);

KD:= CROSS(C,M1) ;       //开多条件
KK:= CROSS(M1,C) ;       //开空条件


开多:BUY(KD AND HOLDING=0,1,THISCLOSE);          //开多信号
开空:BUYSHORT(KK AND HOLDING=0,1,THISCLOSE);     //开空信号

AA:ENTERBARS;
KCH:= REF(HIGH,ENTERBARS+1);
KCL:= REF(LOW,ENTERBARS+1);
KCQH:= ref(hhv(high,10),enterbars+1);
KCQL:= ref(LLv(LOW,10),enterbars+1);
DZY:= ENTERPRICE+(ENTERPRICE-REF(LLV(LOW,10),ENTERBARS+1))*2;
KZY:= ENTERPRICE-(REF(HHV(HIGH,10),ENTERBARS+1)-ENTERPRICE)*2;


PD:= C<KCL  OR C<KCQL OR C>= DZY  ;          //平多条件
PK:= C>KCH OR C>KCQH OR C<= KZY  ;          //平空条件

平多:SELL(PD,1,THISCLOSE);                       //平多信号
平空:SELLSHORT(PK,1,THISCLOSE);                  //平空信号

100020711

通过老师的改写，回测出现惊讶好转。AA:ENTERBARS;这就是全局变量吧？一条单均线可以有万般变化，但在开盘期间的信号有随K线图数据扩大，买卖信号有中断或发生变动的现象，不知道是什么原因？

技术006

100020711 发表于 2024-6-6 10:20
通过老师的改写，回测出现惊讶好转。AA:ENTERBARS;这就是全局变量吧？一条单均线可以有万般变化，但在开盘 ...

不是。等会给你简化一个示例。建议你理解下原来代码的错误原因。有助于提升自己的代码逻辑控制。

100020711

感谢老师的帮助！！！

技术006

[PEL] 复制代码

//全局变量定义
VARIABLE:KCH=0,KCL=0;

M1:EMA(CLOSE,50);

KD:= CROSS(C,M1) ; //开多条件
KK:= CROSS(M1,C) ; //开空条件

if KD=1 then BEGIN
	SELLSHORT(holding<0,1,THISCLOSE);
	BUY(HOLDING=0,1,THISCLOSE);
	//金死叉是交替的，所以直接记录开仓时的最高最低价，如果条件存在多次进入的情况下，还要做更细致的控制。
	KCH:=HIGH;	
	KCL:=LOW;
END

if KK=1 then BEGIN
	SELL(holding>0,1,THISCLOSE);
	BUYSHORT(HOLDING=0,1,THISCLOSE);
	//金死叉是交替的，所以直接记录开仓时的最高最低价，如果条件存在多次进入的情况下，还要做更细致的控制。
	KCH:=HIGH;	
	KCL:=LOW;
END

//其他平仓条件


PD1:= C<KCL;
PK1:= C>KCH;
if PD1=1 AND HOLDING>0 then BEGIN
	平多1:SELL(holding>0,1,THISCLOSE);
END

if PK1=1 AND HOLDING<0 then BEGIN
	平空1:SELLSHORT(holding<0,1,THISCLOSE);
END



KCQH:= ref(hhv(high,10),enterbars);
KCQL:= ref(LLv(LOW,10),enterbars);
DZY:= ENTERPRICE+(ENTERPRICE-KCQL)*2;
KZY:= ENTERPRICE-(KCQH-ENTERPRICE)*2;
PD3:= C>= DZY;                      //收盘大于等于2：1盈亏比平多
PK3:= C<= KZY; //平空条件
平空3:SELLSHORT(PK3,1,THISCLOSE);//平空信号
平多3:SELL(PD3,1,THISCLOSE);//平多信号


//下面部分无效条件,因为开仓当根k的最高价作为止盈价格小于等于KCQH，所以KCH相关的条件会优先触发。
PD2:= C<KCQL ;
PK2:= C>KCQH ; //平空条件
平多:SELL(PD2,1,THISCLOSE);
平空:SELLSHORT(PK2,1,THISCLOSE);//平空信号
//********************************结束*******************************

100020711

万分感激老师的指导！！！